Roca, Papel o Tijera

Este código es una colaboración de: Melvin Guerrero

Descripción:

Juego del clásico roca, papel o tijera creado en Latino

Copiar todo el código

Descargar código .lat

Todos los códigos fueron copiados a su portapapeles

/*
Este juego de roca, papel, tijera está escrito en Latino (un lenguaje de programación con sintaxis al Español).
El código de este juego es un ejemplo de cómo se podría programa el juego de roca, papel y tijeras con Latino.

Juego de roca, papel, tijera en Latino, creado el 15 de Junio, 2019 por Melvin Guerrero
*/


###### Código fuente del juego ######

cabecera="       Usuario       |          COMP
--------------------   --------------------"
      
rocaPapelTijera=["
    _______          |          _______    
---'   ____)         |         (____   '---
      (_____)        |        (_____)      
      (_____)        |        (_____)      
      (____)         |         (____)      
---.__(___)          |          (___)__.---","
    _______          |          _______    
---'   ____)         |     ____(____   '---
      (_____)        |    (______          
      (_____)        |   (_______          
      (____)         |    (_______         
---.__(___)          |      (__________.---","
    _______          |          _______    
---'   ____)         |     ____(____   '---
      (_____)        |    (______          
      (_____)        |   (_______          
      (____)         |         (____)      
---.__(___)          |          (___)__.---","
    _______          |          _______    
---'   ____)____     |         (____   '---
          ______)    |        (_____)      
          _______)   |        (_____)      
         _______)    |         (____)      
---.__________)      |          (___)__.---","
    _______          |          _______    
---'   ____)____     |     ____(____   '---
          ______)    |    (______          
          _______)   |   (_______          
         _______)    |    (_______         
---.__________)      |      (__________.---","
    _______          |          _______    
---'   ____)____     |     ____(____   '---
          ______)    |    (______          
          _______)   |   (_______          
         _______)    |         (____)      
---.__________)      |          (___)__.---","
    _______          |          _______    
---'   ____)____     |         (____   '---
          ______)    |        (_____)      
       __________)   |        (_____)      
      (____)         |         (____)      
---.__(___)          |          (___)__.---","
    _______          |          _______    
---'   ____)____     |     ____(____   '---
          ______)    |    (______          
       __________)   |   (__________       
      (____)         |    (_______         
---.__(___)          |      (__________.---","
    _______          |          _______    
---'   ____)____     |     ____(____   '---
          ______)    |    (______          
       __________)   |   (__________       
      (____)         |         (____)      
---.__(___)          |          (___)__.---"]

victorias=0 //contador de victorias
perdidas=0 //contador de perdidas
resp=""

funcion seleccion(inicio, final)  //función para elegir un número aleatorio
 i=mate.aleatorio(inicio, final)
 retorno i
fin

escribir ("Bienvenido! vamos a jugar a roca, papel, y tijera")
escribir ("¿Estas listo? ( sí(s) o no(n) )")

mientras resp !="s" && resp !="n" //respuesta para empezar a jugar o no
 resp=leer()
fin

si resp=="n" //si la respuesta fue un "no"
 escribir ("Una lastima, y yo que tenia ganas de jugar. Adios :(")
 sis.salir()
osi resp=="s" //si la respuesta fue un "si"
 repetir //hasta que la condición en el comando "hasta" no sea cumplida, se repetirá el código dentro de esta función
  limpiar()
  
  jugarOtraVez=""
  seleccionUsuario=""
  
  escribir ("Registro: Victorias = "..victorias.." | Perdidas = "..perdidas)
  escribir ("Has una seleccion, escribe: 'roca','papel', o 'tijera'")
  
  mientras seleccionUsuario !="roca" && seleccionUsuario !="papel" && seleccionUsuario != "tijera"
   digitar=leer()
   seleccionUsuario=cadena.minusculas(digitar)
  fin
    
  elegir (seleccionUsuario) //se elige una respuesta aleatoria en base a la selección de roca, papel o tijera
    caso "roca":
     x=0
     y=2
     z=seleccion(x,y)
     escribir (cabecera)
     si z==0
      escribir (rocaPapelTijera[z])
     escribir ("\n¡Es un empate!")
     osi z==1
       escribir (rocaPapelTijera[z])
      escribir ("\nhas perdido :(")
      perdidas ++
     sino
       escribir (rocaPapelTijera[z])
      escribir ("\n¡Victoria!")
     victorias ++
     fin     
    caso "papel":
     x=3
     y=5
     z=seleccion(x,y)
     escribir (cabecera)
     si z==3
      escribir (rocaPapelTijera[z])
     escribir ("\n¡Victoria!")
     victorias ++
     osi z==4
       escribir (rocaPapelTijera[z])
      escribir ("\n¡Es un empate!")
     sino
       escribir (rocaPapelTijera[z])
      escribir ("\nhas perdido :(")
     perdidas ++
     fin
    caso "tijera":
     x=6
     y=8
     z=seleccion(x,y)
     escribir (cabecera)
     si z==6
      escribir (rocaPapelTijera[z])
     escribir ("\nhas perdido :(")
     perdidas ++
     osi z==7
       escribir (rocaPapelTijera[z])
      escribir ("\n¡Victoria!")
     victorias ++
     sino
       escribir (rocaPapelTijera[z])
      escribir ("\n¡Es un empate!")
     fin
    defecto: //en caso la respuesta sea distinta
     escribir ("No se a seleccionado ninguna opción")
  fin
  
  funcion otraVez() //se pregunta si se quiere volver a jugar
   mientras jugarOtraVez != "s" && jugarOtraVez !="n"
    escribir ("\n¿Quieres volver a jugar? ( sí(s) o no(n) )")
    jugarOtraVez=leer()
    
    retorno jugarOtraVez
   fin
  fin
    
  jugarOtraVez=otraVez() //se llama la función "otraVez()" y se agrega el valor a la variable "jugarOtraVez"
  
 hasta (jugarOtraVez !="s") //si la siguiente condición no se cumple, el juego se repite
 
 escribir ("\nGracias por jugar!")
fin

###### Fin del juego ######